Het Range object is uitgebreid beschreven in het handboek; blz 114-124. Wellicht is dit het meest gebruikte object in Excel VBA. Enkele voorbeelden; klik op de driehoek om de oplossing te zien!

Selecteer enkele cellen. Druk zowel het adres af van de actieve cel als van het geselecteerde gebied.

Sub voorbeeld1()
    Dim adres As String
    adres = Application.ActiveCell.Address
    adres = adres & vbCrLf & Application.Selection.Address
    MsgBox adres
End Sub

Vraag aan de gebruiker een rij- en kolomnummer en de selecteer de cel op deze rij en kolom.

Sub voorbeeld2()
    Dim rij As Long, kol As Byte
    Dim w As Worksheet
    Set w = Application.ActiveSheet
    rij = InputBox("Geef rijnummer")
    kol = InputBox("Geef kolomnummer")
    w.Cells(rij, kol).Select
End Sub

Vraag aan de gebruiker het adres van twee cellen (linksboven en rechtsonder). Selecteer het gebied tussen deze twee cellen. Gebruik de inputbox-methode voor het opvragen van celreferenties.

Sub voorbeeld3()
    Dim w As Worksheet
    Dim lb As Range, ro As Range
    
    Set w = Application.ActiveSheet
    Set lb = Application.InputBox("LB?", , "$A$1", , , , , 8)
    Set ro = Application.InputBox("RO?", , "$D$5", , , , , 8)
    
    w.Range(lb, ro).Select
End Sub

Selecteer de bovenste rij van het gebied, waar de actieve cel zich bevindt. U mag gelijk welke cel van dit gebied geselecteerd hebben.

Sub voorbeeld4()
   Dim g As Range
   Set g = ActiveCell.CurrentRegion
   g.Rows(1).Select
End Sub

Druk het aantal kolommen af van het geselecteerde gebied. Gebruik een variabele voor deze selectie.

Sub voorbeeld5()
    Dim w As Worksheet, s As Range
    
    Set s = Application.Selection
    MsgBox s.Columns.Count
End Sub

Vergroot de selectie van een gebied met 1 rij en 1 kolom; bijvoorbeeld het gebied A1:C3 wordt A1:D4.  Zie het voorbeeld in de Help onder Resize.

Sub voorbeeld6()
    Dim s As Range
    Set s = Selection
    s.Resize(s.Rows.Count + 1, s.Columns.Count + 1).Select
End Sub

Kleur alle cellen (minder dan 50) in het rood van het gebied A1:E10. Gebruik een For ... Each instructie.

Sub voorbeeld7()
Dim c As Range
    For Each c In Range("A1:E10")
        If c.Value < 50 Then
            c.Interior.Color = vbRed
        End If
    Next c
End Sub

Er zijn verschillende methoden om een Range object te verkrijgen:

• via de eigenschap Range van het Application- of Worksheet-object zoals in Application.Range("A1") of Worksheets("Blad1").Range ("A1")
• via de eigenschap ActiveCell van het Application-object
• via de eigenschap Offset van een Range object zoals in Range("A1").Offset(1, 0) of ActiveCell.Offset(0, 1)
• met behulp van de eigenschap Cells van het Application, Worksheet of Range object zoals in ActiveSheet.Cells(1, 1) of Workbooks(1).Worksheets(2).Cells(1, 1)
• via diverse andere eigenschappen zoals namen; bv. Range("mijnGebied") of de eigenschap UsedRange en CurrentRegion of via de eigenschappen Row en Column.

Het Range object telt vele eigenschappen en methoden. Enkele belangrijke zijn:

• Eigenschappen: Address, Areas, Borders, Cells, ColumnWidth, Count, CurrentRegion, End, EntireColumn, EntireRow, Interior, Offset, RowHeight, Style, Value
• Methoden: Activate, AutoFill, AutoFilter, AutoFormat, Clear, Copy, Cut, Delete, Find, Insert, PrintOut, PrintPreview, Select, Sort